====== Sauvegarder ses documents avec Windows ======
{{ informatique:robocopy_la_sauvegarde_sous_windows.jpg?nolink&75x75|Sauvegarder ses documents}}
Testé **non** | Nécessite {{informatique:icon_terminal.png?nolink&32| terminal}}
Cet article est extrait du podcast [[https://www.abonnel.fr/podcast/?name=2018-11-22_cedric_info_13_robocopy_la_sauvegarde_sous_windows.mp3|mindCast Info, sauvegarder ses documents]]
===== - Objectif =====
J'ai une de mes connaissances qui m'a demandé **comment faire une sauvegarde** avec Windows.\\
Il s'agit bien d'effectuer une réplication des données des documents de l'ordinateur vers une unité de stockage extérieure.
Je me suis fixé comme objectif de **ne pas utiliser de programmes complémentaires** à ceux déjà existants sous Windows et d'essayer de **maitriser au maximum le processus**, avec un **temps minimum à l’exécution**.
Voici mes explications. Travaux pratiques pour effectuer une sauvegarde "intelligente" sous Windows.
Le but est bien de maintenir l’image parfaite des dossiers ou documents de l'ordinateur (appelés __source__) vers une unité de stockage extérieure (appelée __destination__) sans tout recopier systématiquement.
Pour ne pas faire une sauvegarde intégrale de tous vos dossiers à chaque fois, on va essayer d'utiliser un programme qui compare et sauvegarde les modifications des fichiers ou dossiers réalisées à l’aide d’un logiciel.
Pour plus de simplicité, j’ai préféré ne pas utiliser de programmes complémentaires mais uniquement ceux qui sont déjà disponibles sous Windows. Ceci afin que vous puissiez maitriser au maximum le processus, dans un temps raisonnable par son exécution.
===== - Solution =====
Le programme choisi est **robocopy**. Il s'agit d'un programme en **ligne de commande**. Pour l'executer, nous allons programmer les commander dans un fichier d'execution appelé **BATCH**. Ce sont des fichiers terminant par l'extension **.BAT**.
Au premier lancement, le programme fait une copie intégrale de vos documents vers l'unité de sauvegarde. Cela peut prendre beaucoup de temps.\\
Aux lancements suivants, le programme effectue une sauvegarde incrémentielle (suppression, modification et ajout des fichiers), ce qui prend beaucoup moins de temps.
===== - Le code =====
==== - Sauvegardes des dossiers identifiés ====
J'aurai pu identifier les 4 dossiers principaux''Documents'', ''Bureau'', ''Téléchargement'' et le dossier ''[[linux:AppData]]'', mais j'effectue une sauvegarde complète du dossier utilisateur.
@echo off
REM A ecrire dans un fichier sauvegarde_all.bat
REM On sauvegarde tous les dossiers des Users et AppData
REM Adapter les variables ci-dessous si nécessaire
set racine_sauvegarde=e:\sauvegarde
set dossier_sauvegarde=%racine_sauvegarde%\%computername%
if not exist "%TMP%\robocopy" mkdir "%TMP%\robocopy"
set "log_out_script=%TMP%\robocopy\synthese.txt"
set "log_err_robocopy=%TMP%\robocopy\robocopy_%dateTime%_err.txt"
set "log_out_robocopy=%TMP%\robocopy\robocopy_%dateTime%_out.txt"
set rbcpy_errorlevel=0
REM ** on cree le dossier de sauvegarde s'il n'existe pas
IF NOT EXIST "%destination_sauvegarde%" mkdir "%destination_sauvegarde%"
goto save_3
REM ** on commence la sauvegarde 1
set "source_sauvegarde=C:\Users"
set "destination_sauvegarde=%dossier_sauvegarde%\Users"
call :CALLROBOCOPY source_sauvegarde destination_sauvegarde log_out_script
REM ** on commence la sauvegarde 2
set "source_sauvegarde=C:\ProgramData"
set "destination_sauvegarde=%dossier_sauvegarde%\ProgramData"
call :CALLROBOCOPY source_sauvegarde destination_sauvegarde log_out_script
REM ** on commence la sauvegarde 3
:save_3
set "source_sauvegarde=C:\Users\adm_cedric\Documents"
set "destination_sauvegarde=%dossier_sauvegarde%\users\adm_cedric\Documents"
call :CALLROBOCOPY source_sauvegarde destination_sauvegarde log_out_script
GOTO FIN
:ERREUR
echo ********** FIN ANORMALE DU TRAITEMENT *****
exit /B 1
:FIN
REM ** on termine la sauvegarde par marquer un horodatage
echo ********** FIN NORMALE DU TRAITEMENT *****
exit /B 0
rem CALLROBOCOPY SOURCE DESTINATION LOG
rem
rem SOURCE [IN, STR] Nom de la variable contenant le chemin de la source à copier
rem DESTINATION [IN, STR] Nom de la variable contenant le chemin de la destination
rem LOG [IN, STR] Chemin pour accéder au LOG du script
rem
:CALLROBOCOPY
call :GETLOCALDATETIME dateCUR timeCUR
set dateTime=%dateCUR%_%timeCUR%
echo %dateTime% - DEBUT - sauvegarde "%source_sauvegarde%" dans "%destination_sauvegarde%" >>"%log_out_script%"
if not exist "%TMP%\robocopy" mkdir "%TMP%\robocopy"
set "log_err_robocopy=%TMP%\robocopy\robocopy_%dateTime%_err.txt"
set "log_out_robocopy=%TMP%\robocopy\robocopy_%dateTime%_out.txt"
echo Lancement de la copie de %source_sauvegarde%
echo Lancement de la copie de %source_sauvegarde% >>"%log_out_robocopy%"
Robocopy.exe "%source_sauvegarde%" "%destination_sauvegarde%" /E /MIR /Z /DCOPY:T /COPY:DT /TIMFIX /R:0 /W:0 /TEE /NP 1>>"%log_out_robocopy%" 2>>"%log_err_robocopy%"
set rbcpy_errorlevel=%errorlevel%
REM ** on termine la sauvegarde par marquer un horodatage
call :GETLOCALDATETIME dateCUR timeCUR
set dateTime=%dateCUR%_%timeCUR%
echo %dateTime% - FIN - sauvegarde effectuee avec le code %rbcpy_errorlevel% 1>>"%log_out_script%"
if %rbcpy_errorlevel% NEQ 0 (
echo ROBOCOPY s'est executé avec le code erreur %rbcpy_errorlevel%. Vérifier les logs dans %TMP%\robocopy
goto ERREUR
) ELSE (
GOTO :EOF
)
rem GETLOCALDATETIME RESULTDATE RESULTTIME
rem Extraire la date et l'heure independemment des parametres regionaux
rem Extraire la date au format YYYYMMDD et l'heure au format HHMMSS
rem RESULTDATE [OUT, STR] Nom de la variable contenant le date au format YYYYMMDD
rem RESULTDATE=0 si la date n'a pas pu etre extraite
rem RESULTTIME [OUT, STR] Nom de la variable contenant l'heure au format HHMMSS
rem RESULTTIME=0 si l'heure n'a pas pu etre extrait
:GETLOCALDATETIME
set RESULT=
for /f "tokens=* skip=1 delims=" %%A in ('wmic os get LocalDateTime') do (
if not defined RESULT set RESULT=%%A
)
if not defined RESULT set RESULT=0
if %RESULT%==0 (
if "%~1" NEQ "" (set %~1=%RESULT%)
if "%~2" NEQ "" (set %~2=%RESULT%)
) else (
if "%~1" NEQ "" (set %~1=%RESULT:~0,8%)
if "%~2" NEQ "" (set %~2=%RESULT:~8,6%)
)
goto :EOF
Il ne faut pas modifier les fichiers et dossiers de la sauvegarde externe au risque de perdre votre travail.
==== - Sauvegardes les dossiers de tous les utilisateurs ====
Pour se simplifier la tâche on pourrait sauvegarder tous les fichiers et dossiers présents dans le dossier des utilisateurs.\\
Mais ce n'est pas si simple, car les dossiers des utilisateurs peuvent être protégés en lecture. Il faudrait avoir des droits plus étendus. On parle alors de droit ACL. Une exécution du script avec les droits administrateur permettrait de contourner le problème.
REM A ecrire dans un fichier sauvegarde_all.bat
REM Adapter les variables ci-dessous si nécessaire
set source_sauvegarde=%homedrive%%homepath%\..
set racine_sauvegarde=e:\sauvegarde
set destination_sauvegarde=%racine_sauvegarde%\%computername%
REM **************************************
REM ***** NE PAS MODIFIER EN DESSOUS *****
REM **************************************
REM ** on cree le dossier de sauvegarde s'il n'existe pas
IF NOT EXIST "%destination_sauvegarde%" mkdir -p "%destination_sauvegarde%"
REM ** on commence la sauvegarde
Robocopy.exe "%source_sauvegarde%\\" "%destination_sauvegarde%" /E /MIR /Z /DCOPY:T /COPY:DT /TIMFIX /R:0 /W:0 /TEE /NP
REM ** on termine la sauvegarde par marquer un horodatage
set dateCUR=%date:~6,4%%date:~3,2%%date:~0,2%
set timeCUR=%time:~0,2%%time:~3,2%%time:~6,2%
set dateTime=%dateCUR%_%timeCUR%
echo %dateTime% sauvegarde "%source_sauvegarde%" dans "%destination_sauvegarde%" effectuee >>"%racine_sauvegarde%\infos.txt"
===== - Vérification =====
Il va falloir vérifier que les fichiers contenu dans la **source** soit également dans la **destination**. Pas un de plus, pas un de moins. C'est là que les choses se corsent. Lors de mes tests, il est apparu que l'explorateur de fichier calculé n'importe quoi, n'importe comment.\\
Il a fallu que je retourne dans une fenêtre de **ligne de commandes** (fenêtre DOS) et jouer avec la commande ''dir''.
Je vous détaillera cela ultérieurement. Revenez plus tard sur cette page SVP.
===== - Évolutions =====
Prochainement
* une vidéo pour montrer comment j'ai fait.
* la vérification du contenu synchronisé.
* le changement de lecteur à chaque branchement d'un disque externe ?
* faut-il préférer une sauvegarde externe ou interne ?
* faut-il faire confiance à une sauvegarde sur clé USB, disque SSD, DVD ?
* corriger les fautes.
* compléter l'article suivant vos retours